·您现在的位置：云翼网络 >> 文章中心 >> 网站建设 >> 网站建设开发 >> ASP网站建设 >> 2栏分页显示（附显示的形式前页，后页）

2栏分页显示（附显示的形式前页，后页）

作者：佚名 ASP网站建设编辑：admin 更新时间：2022-07-23

显示形式：
         ID1     NAME   | ID2   NAME
         1       JULIET |  2     PALYBOY
         3       BABY   |  4     TOM
         5       LENA   |  6      JERY
>>首页前页后页尾页  页数：1/4  6条/页   总记录数:25条
代码：


<html>
<body bgcolor="#FFFFFF" text="#000000">
<table width="60%" border="1" align="center">
<%
    dim rs
    dim sql
    msg_per_page    =    4                                                        '定义每页显示记录条数
    set rs    =    server.createobject("adodb.recordset")
    sql = "select * from page order by id"                                      '改成你自己的SQL语句
    rs.cursorlocation    =    3                                                    '使用客户端游标，可以使效率提高

    rs.pagesize    =    msg_per_page                                                '定义分页记录集每页显示记录数
    rs.open sql,conn,0,1

    if err.number<>0 then                                                        '错误处理
        response.write "数据库操作失败：" & err.description
        err.clear
    else
        if not (rs.eof and rs.bof) then                                            '检测记录集是否为空
            totalrec    =    RS.RecordCount                                        'totalrec：总记录条数
            if rs.recordcount mod msg_per_page    =    0 then                        '计算总页数,recordcount:数据的总记录数
                n    =    rs.recordcount\msg_per_page                                'n:总页数
            else
                n    =    rs.recordcount\msg_per_page+1
            end if

            currentpage    =    request("page")                                        'currentpage:当前页
            If currentpage <> "" then
                currentpage =  cint(currentpage)
                if currentpage < 1 then
                    currentpage = 1
                end if
                if err.number <> 0 then
                    err.clear
                    currentpage    =    1
                end if
            else
                currentpage = 1
            End if
            if currentpage*msg_per_page > totalrec and not((currentpage-1)*msg_per_page < totalrec)then
                currentPage=1
            end if
            rs.absolutepage    =    currentpage                                    'absolutepage：设置指针指向某页开头
            rowcount        =    rs.pagesize                                    'pagesize：设置每一页的数据记录数

            dim i
            dim k
%>
        <tr align="center" valign="middle">
            <td width="25%">ID1</td>
            <td width="25%">name1</td>
            <td width="25%">ID2</td>
            <td width="25%">name2</td>
        </tr>
        <%do while not rs.eof and rowcount > 0%>
        <tr align="center" valign="middle">
            <td width="25%"><%=rs("id")%></td>
            <td width="25%"><%=rs("testname")%></td>
            <td>
                <%
                    rowcount=rowcount-1
                    rs.MoveNext
                    if not rs.EOF then
                %>
                        <%=rs("id")%>
            </td>
            <td width="25%"><%=rs("testname")%></td>
        </tr>
<%
                        rowcount=rowcount-1
                        rs.MoveNext
                    else
                        Response.Write " </td><td> </td></tr>"
                    end if
          loop
        end if
    end if
    rs.close
    set rs=nothing
%>

</table>
<table border="0" align="center">
  <tr>
    <td align="center" valign="middle">
      <%call listPages()%>
    </td>
  </tr>
</table>
</body>
</html>
<%
    sub listPages()
        if n <= 1 then exit sub
%>
        <p><span class=smallFont>>>
        <%if currentpage    =    1 then%>
            <font color=darkgray face="arial" >Top PRevious</font>
        <%else%>
            <font color=black face="arial"><a href="<%=request.ServerVariables("script_name")%>?page=1">Top</font></a>
            &nbsp<a href="<%=request.ServerVariables("script_name")%>?page=<%=currentpage-1%>">
            <font color=black face="arial" >Previous</a></font>
        <%end if%>
        <%if currentpage    =    n then%>
            <font color=darkgray face="arial" >Next Bottom</font>
        <%else%>
            <font color=black face="arial" ><a href="<%=request.ServerVariables("script_name")%>?page=<%=currentpage+1%>">Next</a>
            &nbsp<a href="<%=request.ServerVariables("script_name")%>?page=<%=n%>">Bottom</a></font>
        <%end if%>
        <font color=black face="arial" >
        &nbsp Page:<%=currentpage%>/<%=n%>pages&nbsp&nbsp<%=msg_per_page%>notes/page &nbsp Total:<%=totalrec%>notes</font></span></p>
  <%end sub%>

上一篇文章： 2栏分页显示（附显示的形式[1][2]）
下一篇文章：购物车范例（购物车页面）

2栏分页显示（附显示的形式前页，后页）

网站建设问答

网站建设开发

网站需求分析